Große Klappe

Kalender basteln mit LibreOffice

28.12.2012 Es klingt ein wenig wahnwitzig, aber tatsächlich lässt sich mit ein paar Calc-Formeln ein schlichter, aber funktionaler Klappkalender basteln, der auch noch in den nächsten Jahren funktioniert.

Potzblitz! Das Kalenderjahr 2013 hat bereits begonnen und noch immer steht kein neuer Klappkalender auf dem Schreibtisch. Was liegt da näher, als sich mit LibreOffice Calc den Tischkalender selbst zu erstellen? Mit den passenden Formeln ist das im Handumdrehen erledigt. Und: Ihr Kalender zeigt sogar die Kalenderwochen an, hebt Wochenenden farbig hervor und kennt die gesetzlichen Feiertage.

Im Workshop erzeugen Sie einen Jahresklappkalender, den Sie mit Hilfe von Schaltflächen auch schnell für das folgende oder das zurückliegende Kalenderjahr nutzen (Abbildung 1).

Abbildung 1

Abbildung 1: So sieht der fertige Klappkalender aus, den Sie in der Mitte falten und auf den Tisch stellen.

Dreh- und Angelpunkt: Das Kalenderjahr

Als zentrale Zelle, also als Ausgangspunkt für den gesamten Kalender, dient die Zelle A36. Sie enthält das aktuelle Kalenderjahr, das Sie mit Hilfe von Schaltflächen umschalten. In diese Zelle schreiben Sie den Wert 2013. Weil die Zelle zugleich als Überschriftenzeile des Kalenders auftritt, verbinden Sie danach die Zellen A36 bis N36 und formatieren diese mit einem benutzerdefinierten Zahlenformat, damit als Überschrift Kalenderjahr 2013 erscheint.

Dazu markieren Sie die Zellen A36 bis N36, klicken Sie mit der rechten Maustaste an und wählen Zellen verbinden. Dann wählen Sie Format / Zellen und rufen unter Kategorie den Eintrag Benutzerdefiniert auf. In die Zeile Formatcode schreiben Sie "Kalenderjahr "Standard. Die Überschrift zentrieren Sie horizontal und vertikal in der Mitte und verpassen ihr eine geeignete Schriftgröße und Schriftart. Die weitere Formatierung der verbundenen Zellen – etwa die Farbgebung – ist wie immer Geschmackssache.

Alles dreht sich

Nun fügen Sie eine Schaltfläche ein, um das angezeigte Kalenderjahr zu steuern. Dazu öffnen Sie über Ansicht / Symbolleisten / Formular-Steuerelemente die gleichnamige Symbolleiste und klicken auf das Symbol Entwurfsmodus an/aus, um den Entwurfsmodus einzuschalten. Aus den Werkzeugen wählen Sie das mit dem Tooltipp Drehfeld (Abbildung 2) aus. Mit dem zu einem Fadenkreuz veränderten Mauszeiger ziehen Sie jetzt irgendwo ein Rechteck auf, das ungefähr die Größe des gewünschten Drehfeldes besitzt. Lassen Sie den Mauszeiger los, sehen Sie das eingefügte Drehfeld mit acht Ziehpunkten. In diesem Modus passen Sie das Symbol noch in der Größe an und verschieben es dann an den gewünschten Platz in der Tabelle – idealerweise an den Anfang oder an das Ende der Überschriftenzeile mit dem angezeigten Kalenderjahr.

Abbildung 2

Abbildung 2: Über die Symbolleiste "Formular-Steuerelemente" fügen Sie ein Drehfeld ein, über das Sie später zwischen den Jahren umschalten.

Damit das Drehfeld funktioniert, müssen Sie es mit der Zelle A36 (die mit dem Kalenderjahr) verbinden. Dazu öffnen Sie im Entwurfsmodus mit einem Rechtsklick auf das eingefügte Drehfeld das Kontextmenü und wählen daraus den Eintrag Kontrollfeld. Das öffnet die Dialogbox Eigenschaften: Drehfeld, die drei Reiter besitzt.

Im Register Allgemein bestimmen Sie die wesentlichen Eigenschaften der Schaltfläche, also das Aussehen und die angezeigten Werte. Bei Min. Wert tragen Sie das frühestmögliche Kalenderjahr ein, etwa 1999. In das Feld Max. Wert schreiben Sie das gewünschte Kalenderjahr der Zukunft, etwa 2100. Dass Sie dann aber Ihren Kalender noch mit LibreOffice Calc entwerfen, lässt sich bezweifeln. Als Standardwert benutzen Sie das Kalenderjahr, das der Kalender beim Öffnen der Datei anzeigen soll, aktuell also 2013.

In das Feld Intervall gehört der Wert 1, damit Calc beim Klick auf das Drehfeld immer das nächste oder vorhergehende Kalenderjahr präsentiert. Über Hintergrundfarbe färben Sie die Schaltfläche ein, über Symbolfarbe die beiden Richtungspfeile. Wollen Sie die Richtungspfeile vertikal ausrichten, stellen Sie dies bei Orientierung ein. Damit Calc die Schaltfläche beim Drucken nicht mit ausdruckt, ändern Sie den Befehl Druckbar von Ja auf Nein (Abbildung 3). Nun müssen Sie Calc mitteilen, auf welche Zelle sich die Eintragungen auswirken. Dazu tragen Sie im Reiter Daten bei Verknüpfte Zelle den Wert A36 ein, was die Zelle A36 meint (Abbildung 4).

Ein Klick auf das Symbol Entwurfsmodus an/aus in der Symbolleiste Formular-Steuerelemente beendet den Entwurfsmodus und lässt die Dialogbox verschwinden. Das Drehfeld ist nun einsatzbereit, was Sie mit einem Probeklick leicht überprüfen. Die Überschriftenzeile mit dem Kalenderjahr der ersten Hälfte des Klappkalenders ist fertig.

Im nächsten Schritt erstellen Sie die Überschriftenzeile für die Rückseite des Klappkalenders. Sie müssen nur in die Zelle B34 die Verknüpfung =A36 schreiben. Nachdem Sie die Zellen B34 bis O34 wieder in eine verbundene Zelle verwandelt haben, formatieren Sie diese wie Zelle A36, um das gleiche Aussehen zu erhalten. Damit die Zahlen auf dem fertigen Kalender nicht auf dem Kopf stehen, weisen Sie dem Text über Format / Zellen im Reiter Ausrichtung einen Winkel von 180 Grad zu. Die Höhe der Zeile 35 verschmälern Sie über die Leiste links auf 0,15 cm, denn hier klappen Sie später den Kalender um.

Abbildung 3

Abbildung 3: Sie müssen nicht alle Eigenschaften des Drehfeldes verändern, um es für Ihre Zwecke anzupassen.

Abbildung 4

Abbildung 4: Das Drehfeld nimmt Bezug auf eine existierende Zelle, in der die aktuelle Jahreszahl steht.

Die Zeilen mit den Monatsnamen

Die Zeile 33 enthält ab Spalte B in jeder zweiten Spalte (B33, D33, F33 und so weiter) die Monatsnamen: Sie reichen vom Januar des Folgejahres (B33) bis zum Juli des angezeigten Kalenderjahres (N33). Auch die Zeile 37 enthält ab Spalte A in jeder zweiten Spalte (A37, C37, E37 etc.) die Monate vom Dezember des Vorjahres (A37) bis zum Juni des aktuellen Kalenderjahres (M37).

Sie schreiben aber nicht einfach die Namen in die Zellen. Calc ordnet die einzelnen Tage später den richtigen Wochentagen des jeweiligen Kalenderjahres zu, indem es die Monatsnamen aus dem Kalenderjahr in der Zelle A36 ableitet. Den Dezember des Vorjahres bildet die Funktion DATUM(Jahr; Monat; Tag) ab und die sieht so aus:

=DATUM($A$36-1;12;1)

Der tatsächliche Inhalt der so ermittelten Zelle ist also immer der 01. des jeweiligen Monats. Formatieren Sie die Zelle benutzerdefiniert mit dem Zahlenformat MMM JJJJ damit Calc Dez 2012 anzeigt.

Den 01. Januar 2014 ermittelt die Formel =DATUM($A$36+1;1;1), den ersten Tag des Februars 2013 mit =DATUM($A$36;2;1) und so weiter. Als Format-Code verwenden Sie hier MMMM, damit Calc nur die Monatsnamen zeigt.

Die Monatsnamen der Zeile 33 stellen Sie wieder über Format / Zellen und den Reiter Ausrichtung auf den Kopf, damit sie im fertigen Kalender korrekt auftauchen. Das gleiche gilt übrigens für die später noch einzufügenden Werte des gesamten zweiten Halbjahres (also für den gesamten Bereich B2:O33).

Weil Sie für das Erfassen der Kalendertage immer zwei Spalten verwenden, gelten auch die Monatsüberschriften stets für zwei Spalten. So bezieht sich der Januar auf die Zellen der Spalten C und D ab Zeile 37. Das heißt, Sie müssen die Zellen C37 und D37 verbinden und gemeinsam formatieren – das betrifft alle Monatsüberschriften (Abbildung 1).

Feiertage und Wochennummern

Aus optischen Gründen verwenden Sie für jeden Tag zwei Spalten. Sie formatieren die Tage der ersten Tagesspalte, etwa im Bereich A38 bis A68, mit dem Format-Code TT, damit Calc sie mit Werten zwischen 01 und 31 darstellt. Die Software leitet die Zahlen aus den Werten der Monatsüberschriftenzelle ab. Die Tageszahl von A38 entspricht also dem Wert der Überschrift von A37 – nur diesmal im Format-Code TT.

Sie weisen der Zelle A38 also die Formel =A37 zu, sie verweist auf den ersten Tag im Dezember 2012. Den Wert der Zelle A39 ermittelt die Formel = A38+1, den der Zelle A40 die Formel =A39+1 und so weiter. Es genügt daher, den ermittelten Wert der Zelle A39 über das kleine schwarze Ausfüllkästchen bis zur Zelle A68 nach unten zu ziehen – das betrifft alle Zellen der jeweils ersten Tagesspalte. Nicht existierende Tage (etwa den 31. Februar) löschen Sie.

Eine Besonderheit von Calc zeigt sich bei den Zahlen der zweiten Kalenderhälfte: Erhält die Zelle O32 den Wert = N33 und ermitteln Sie den Wert der Zelle O31 mit der Formel =O32+1, setzt Calc die Werte der Zellen O30:O2 durch einfaches Ziehen des Ausfüllkästchens der Zelle O31 automatisch ein – aber diesmal müssen Sie das Kästchen nach oben ziehen.

Der 29. Februar.

Eine Sonderstellung nimmt der 29. Februar ein. Damit der Kalender bei Jahren mit nur 28 Monatstagen nicht den 01. März als letzten Februartag anzeigt, verwenden Sie in dieser Tageszelle (konkret in der Zelle E66) folgende Formel:

=WENN(MONAT(E65+1)<>MONAT($E$37);"";E65+1)

Dadurch zeigt Calc den 29. Februar nur in einem Schaltjahr an und lässt die Zelle sonst leer.

Der Wochentag im Klartext

Haben Sie alle Datumszahlen in die jeweils erste Tagesspalte eingefügt, ergänzen Sie die dazugehörige zweite Tagesspalte. Die entspricht grundsätzlich der ersten Tagesspalte, mit dem Unterschied, dass der Kalender den jeweiligen Tag mit zwei Buchstaben (also etwa Mo für Montag) ausweist. Zusätzlich soll an jedem Montag die Nummer der Kalenderwoche erscheinen und – falls es einen Feiertag gibt – noch dessen Name. Dies alles realisiert eine WENN()-Formel, die das jeweilige Datum hinsichtlich dieser Erfordernisse überprüft und das zutreffende Ergebnis ausweist.

Im einfachsten Fall, also wenn der Tag weder ein Feiertag ist, noch ein Montag mit Wochennummer, soll Calc nur den Wochentag ausweisen. Dies darf in einer WENN()-Formel aber nicht mit einem einfachen Verweis geschehen, etwa =E66, weil die Formel unformatierte Zahlen (also 41275 für den 1. Januar 2013) liefert. Dem Ergebnis müssen Sie also mit der Funktion TEXT() das richtige Format zuweisen, hier mit der Formel:

=TEXT(E66;"TTT")

Erst diese Formel zeigt das gewünschte Ergebnis, also etwa Mo für Montag. Allerdings handelt es sich nicht um die vollständige Formel, wie Sie gleich lesen.

Ermittlung der Kalenderwoche

Am Montag soll der Kalender ansonsten neben dem Wochentag auch die aktuelle Kalenderwoche anzeigen. Dazu müssen Sie die bisherige Formel in der Zelle B38 abändern:

=WENN(WOCHENTAG(A38)=2;TEXT(A38;"TTT")&"   KW "  &KALENDERWOCHE(A38;1);A38)

Diese Formel prüft an jedem Tag, ob der Wochentag der besagten Zelle ein Montag ist (WOCHENTAG = 2). Ist dies der Fall, weist Calc den Kalendertag dieser Zelle mit dem Format-Code TTT – wie oben beschrieben – als Text aus. Dann folgen der Text " KW " (drei Leerzeichen vor KW, eines danach) sowie die errechnete Kalenderwoche (KALENDERWOCHE(A38;1)). Zusätzlich müssen Sie den Inhalt der Zelle linksbündig ausrichten und als Format-Code wieder TTT angeben. Doch tragen Sie auch diese Formel noch nicht kalenderweit ein, es geht noch weiter mit den Feiertagen.

Feiertage einfügen

Für Feiertage gibt es leider keine eingebaute Funktion, die Calc abfragen könnte. Deshalb müssen Sie selbst eine Feiertagsliste anlegen, solche Listen finden Sie zum Beispiel hier [1]. Diese fügen Sie in einem freien Bereich der Kalendertabelle ein – beispielsweise irgendwo rechts daneben oder in einer eigenen Tabelle. Anschließend vergleichen Sie die Datumsangaben des Kalenders mit dieser Liste und weisen so Feiertage im Kalender aus. Für dieses Beispiel nehmen wir an, dass Sie die gesamte Liste der Feiertage in der Tabelle2 ablegen. Diese benennen Sie über einen Rechtsklick auf den Reiter Tabelle2 und über den Menüpunkt Tabelle umbenennen in Feiertage um. Im Tabellenbereich A2:A100 (Abbildung 5) fügen Sie die Daten der Feiertage ein, in die Zellen B2:B100 kommen die zugehörigen Namen. In der Zeile 1 sehen Sie die Überschriften.

Die Datumswerte in Spalte A tragen Sie mit Hilfe der Funktion DATUM(Jahr; Monat; Tag) ein, etwa =DATUM(Kalender.A36;12;24) für Heiligabend, =OSTERSONNTAG(Kalender.A36)-2 für Karfreitag, =DATUM(Kalender.A36;1;1) für Neujahr und so weiter. Auf diese Weise verwenden Sie die Liste für jedes Kalenderjahr, das die Zelle A36 der Tabelle Kalender anbietet. Letztere müssen Sie dazu, wie eben gezeigt, von Tabelle1 in Kalender umbenennen, damit jeder Benutzer sofort merkt, um welche Tabellenblätter es sich handelt. Zum Schluss weisen Sie der Liste noch das gewünschte Datumsformat zu, in diesem Fall TT.MM.JJ. Damit die Feiertage auch mit ihrem Namen im Kalender erscheinen, tragen Sie in die danebenliegende Spalte B ihre Namen ein.

Zur einfacheren Handhabung markieren Sie nun den Datumsbereich Feiertage.A2:A100 und versehen ihn über Einfügen / Namen / Festlegen mit dem Namen Feiertage. Da sich der gesamte Feiertagsabschnitt aber auf den Bereich Feiertage.A2:B100 erstreckt, markieren Sie auch diesen und nennen ihn Feiertagsbereich.

Die Spalte C der Tabelle Feiertage enthält zusätzlich sämtliche in Spalte A verwendeten Formeln in lesbarer Form. Möglich macht dies die Funktion =FORMEL() – in Zelle C2 heißt sie etwa =FORMEL(A2).

Abbildung 5

Abbildung 5: Im Internet gibt es zahlreiche Listen, welche die Feiertage nach Bundesländern aufdröseln. Aus ihnen erstellen Sie die Tabelle "Feiertage".

Für die zum Anzeigen des Feiertags verwendete Formel spielt es keine Rolle, ob Sie in die Feiertagsliste zuerst die Feiertagsnamen und dann die Datumswerte oder beides in umgekehrter Reihenfolge eingeben. Sie müssen die Feiertagsliste auch nicht chronologisch sortieren. Die Formel, die diese Bedingungen erfüllt und den Feiertagsnamen liefert, besitzt exemplarisch folgenden Aufbau:

=WENN(ISTNV(VERGLEICH(<Datumskriterium>;
<Datumsbereich des Feiertagsbereich>;0));
"";INDEX(<gesamter Feiertagsbereich>;
VERGLEICH(<Datumskriterium>;
<Datumsbereich des Feiertagsbereich>;0);
<Index der Namensspalte des Feiertagsbereich>))

In der Tabelle Feiertage finden Sie die Feiertage in den Spalten A und B, den gesamten Feiertagsbereich unter Feiertage.A2:B100. Den Datumsbereich des Feiertagsbereich haben Sie bereits mit Feiertage gelabelt (A2:A100). Der Parameter Index der Namensspalte des Feiertagsbereich gibt an, in welcher Spalte des Feiertagsbereichs Sie die Namen der Feiertage finden. Im Beispiel handelt es sich um Spalte B – der Index erhält somit den Wert 2. Gehen Sie weiterhin davon aus, dass Sie das Datumskriterium von Zelle C38 verwenden, lautet die mit Werten gefüllte Formel:

=WENN(ISTNV(VERGLEICH(C38;Feiertage;0));"";
" - "&INDEX(Feiertagsbereich;VERGLEICH(C38;Feiertage;0);2))

Diese prüft zuerst mit Hilfe der Funktion ISTNV(), ob das gesuchte Datum überhaupt in der Feiertagsliste existiert. Die Suche erfolgt über die Funktion VERGLEICH(Suchkriterium; Suchmatrix; Typ), die den Fehlerwert #NV zurück gibt, wenn sie keine Übereinstimmung findet. Dieser Wert lässt die Funktion ISTNV() "wahr" werden, weshalb die umgebende WENN-Abfrage das "Dann-Ergebnis" ausgibt – was hier aus einer leeren Zeichenfolge (zwei Anführungszeichen) besteht.

Bei einer Übereinstimmung erhalten Sie den Feiertagsnamen über die Funktion INDEX(Bezug; Zeile; Spalte; Bereich). Diese liefert den Wert am Schnittpunkt einer Zeile und einer Spalte aus der Feiertagsliste. Aus welcher Zeile der Wert stammt, bestimmt die bereits bekannte Funktion VERGLEICH(), die – im Gegensatz zu anderen Verweisfunktionen – nicht den Wert, sondern die Position der Fundstelle liefert. Die Spaltenposition für die INDEX()-Funktion richtet sich nach dem Aufbau der Feiertagstabelle – in diesem Fall befinden sich die Namen in Spalte 2.

Die komplette verknüpfte Formel in der Zelle D38 sieht am Ende also so aus:

=TEXT(C38;"TTT")&WENN(ISTNV(VERGLEICH(C38;Feiertage;0));
WENN(WOCHENTAG(C38)=2;"   KW "&KALENDERWOCHE(C38;1);"");
" - "&INDEX(Feiertagsbereich;VERGLEICH(C38;Feiertage;0);2))

Geben Sie in die Zelle C38 ein Datum ein, erscheint in der Zelle D38 der Wochentag im Zahlenformat TTT zusammen mit dem Feiertagsnamen oder – wenn es keinen Feiertag gibt und der Wochentag auf einen Montag fällt – zusammen mit der errechneten Kalenderwochennummer. Diese Formel kopieren Sie und fügen sie in allen übrigen Monatstageszellen (etwa Spalte B, D etc.) ein. Eine Ausnahme bildet Zelle F66, die den Wochentag zum 29. Februar anzeigt. Hier stellen Sie vor die eben gezeigte Formel (bei der Sie das = entfernen) noch einen zusätzlichen Teil:

=WENN(MONAT(E65+1)<>MONAT($E$37);"";

Der sorgt dafür, dass der Wochentag auch im Schaltjahr auftaucht.

Wochenenden einfärben

Wochenenden – also Samstage und Sonntage – ermitteln Sie sehr einfach mit der Funktion WOCHENTAG(Datum; Art) und heben Sie mit einer bedingten Formatierung hervor. Fehlt der Funktionsparameter Art, oder ist der Wert 1, zählt Calc die Wochentage ab Sonntag, bei einem Wert von 2 ab Montag.

Bevor Sie die bedingte Formatierung zuweisen, erstellen Sie am besten eine mit Wochenende benannte Zellvorlage (über [F11] und Neue Vorlage aus Selektion) mit einer entsprechenden Farbe.

Dann klicken Sie auf die erste Tageszelle der ersten Tagesspalte des Monats (beispielsweise C38) und rufen den Befehl Format / Bedingte Formatierung auf. In der erscheinenden Dialogbox wählen Sie bei 1. Bedingung im Listenfeld Formel ist und schreiben in das danebenliegende Eingabefeld die Formel:

ODER(WOCHENTAG(C38)=1;WOCHENTAG(C38)=7)

Als Zellvorlage weisen Sie die vorher erstellte Zellvorlage Wochenende zu. Ein Klick auf OK übernimmt die bedingte Formatierung. Mit dem Formatpinsel übernehmen Sie diese Formatierung für alle übrigen Tage der Spalte. Dazu markieren Sie die Zelle, deren Formatierung Sie übernehmen wollen, klicken dann auf das Icon mit dem gelben Pinsel (Format übertragen) in der Symbolleiste und markieren mit dem Pinsel die Zellen, welche die Formatierung übernehmen sollen. Alternativ kopieren Sie die Zelle mit der gewünschten Formatierung, markieren die Zellen, auf die Sie diese übertragen wollen und wählen Bearbeiten / Inhalte einfügen, wobei Sie im folgenden Fenster nur das Häkchen bei Formate stehen lassen.

Feiertage in Farbe

Als nächstes erweitern Sie die bedingte Formatierung des Kalenders um ein zusätzliches Kriterium. Dazu markieren Sie die Zellen der Kalendertage, denen Sie bereits im ersten Teil eine bedingte Formatierung (für die Wochenenden) zugewiesen haben. Dann rufen Sie wieder den Befehl: Format / Bedingte Formatierung auf. Im nun angezeigten Dialogfenster mit den Bedingungen für die Wochenenden, aktivieren Sie Bedingung 2. Im ersten Drop-down-Feld des Bedingungsfeldes ändern Sie danach den Eintrag von Zellwert ist auf Formel ist. In das Feld rechts daneben tragen Sie die Formel ein, mit der Sie die Datumswerte des Kalenders mit der Feiertagsliste abgleichen:

NICHT(ISTNV(VERGLEICH(C38;Feiertage;0)))

Diese Formel nimmt an, dass C38 die erste Datumszelle des Monats ist. Die Funktion VERGLEICH() liefert die Position im Feiertagsbereich, wenn ein Datum des Kalenders mit einem Feiertagsdatum übereinstimmt. Ansonsten gibt die Funktion den Fehlerwert #NV zurück. Somit fragen Sie in der bedingten Formatierung ab, ob der Feiertagsvergleich NICHT #NV ist. Erweist sich diese Bedingung als "wahr", handelt es sich um einen Feiertag und Calc weist diesem die Vorlage Wochenende oder eine eigens erstellte Vorlage Feiertage zu.

Haben Sie die bedingte Formatierung sowohl für Feiertage als auch für Wochenenden festgelegt, zeigt die Reihenfolge, welche der bedingten Formatierungen Vorrang hat. Wurde die Feiertagsbedingung als zweites Kriterium hinzugefügt, berücksichtigt Calc sie auch erst nach der Wochenendbedingung! Ein Feiertag, der also auf einen Samstag oder Sonntag fällt, erscheint im Wochenendformat. Wollen Sie, dass die Feiertagsbedingung Vorrang hat, müssen Sie Bedingung 1 und Bedingung 2 tauschen – und dazu leider auch neu definieren und zwar für beide Datumsspalten des Kalenders.

Der 29. Februar im Schaltjahr

In der ersten Datumsspalte müssen Sie nun die Bedingte Formatierung für den 29. Februar in Zelle E66 noch um eine dritte Bedingung erweitern, um dem sich verändernden Monatswechsel Rechnung zu tragen. Diese muss Calc als Bedingung 2 erfassen, um alle Eventualitäten zu berücksichtigen (Abbildung 6). Löschen Sie also die Bedingung 2, legen Sie diese neu an und schreiben Sie die Formel:

MONAT(E66)<>MONAT(E$37)

in das Eingabefeld. Der weisen Sie nun die Zellvorlage Standard zu. Dann fügen Sie eine Bedingung 3 ein und setzen hier die ehemalige Formel aus Bedingung 2 ein.

Abbildung 6

Abbildung 6: Für den 29. Februar in Zelle "E66", der nur erscheint, wenn es sich um ein Schaltjahr handelt, legen Sie eine zusätzliche "Bedingte Formatierung" an.

Restarbeiten und Ausdruck

Für den Druck versehen Sie alle Zellen noch mit einer Umrandung. Dazu markieren Sie den Bereich B2:O34, rufen über Format / Zellen die Dialogbox Zellen formatieren auf und wechseln zum Reiter Umrandung. Im Abschnitt Linienanordnung wählen Sie das Symbol Äußere Umrandung und alle inneren Linien zeichnen und weisen den Linien eine graue Farbe zu. Ein Klick auf OK übernimmt die Formatierung. Mit dem Zellbereich A37:N68 verfahren Sie ebenso (Abbildung 7). Als Faltmarken weisen Sie den Zellen A2 und O2 eine obere und den Zellen A69 und O69 eine untere Umrandungslinie zu.

Nun legen Sie den Druckbereich fest. Dazu markieren Sie den gesamten Kalender, also den Bereich A1:O69 und wählen den Befehl: Format / Druckbereiche / Festlegen. Anschließend klicken Sie auf Ansicht / Seitenumbruch-Vorschau, um die Druckansicht aufzurufen. Aus dem Kontextmenü (das Sie per Rechtsklick aufrufen) wählen Sie Seitenformat und wechseln zum Register Seite. Nach den Randeinstellungen aktivieren Sie bei Layouteinstellungen / Tabellenausrichtung die beiden Optionsfelder Horizontal und Vertikal. In den Registern Kopfzeile und Fußzeile schalten Sie beide Optionen ab. Nach dem Wechsel zum Reiter Tabelle wählen Sie im Abschnitt Skalieren als Skalierungsmodus den Eintrag Druckbereich(e) auf Höhe/Breite anpassen. Mit OK übernehmen Sie die Einstellungen. Die Seitenansicht zeigt jetzt eine Vorschau des druckfertigen Kalenders, den Sie mit einem Klick auf das Druckersymbol sofort ausdrucken können.

Abbildung 7

Abbildung 7: Vor dem Ausdrucken weisen Sie den Zellen des Klappkalenders noch Umrandungen zu.

Infos

[1] Feiertage im Überblick: http://feiertage.net/frei-tage.php

Tip a friend    Druckansicht beenden Bookmark and Share
Kommentare