Besser arbeiten mit LibreOffice

LibreOffice-Tipps

07.10.2012
Wir zeigen diesmal in den LibreOffice-Tipps, wie Sie die Durchschnittsnote eines Schulfaches errechnen, Tabellentext automatisch formatieren, Sonderzeichen und Umlaute ersetzen und einiges mehr.

Tipp: Calc: Absolute in relative Bezüge umwandeln

Formeln verwenden wahlweise absolute und relative Bezüge, um Zellen anzusprechen. Standardmäßig geht Calc davon aus, dass eine Formel relative Bezüge verwendet, was ein problemloses Kopieren der Formeln erlaubt. Um absolute Bezüge einzustellen, geben Sie entweder sowohl vor dem Spaltenbuchstaben als auch vor der Zeilennummer ein $-Symbol ein oder Sie drücken [Umschalt]+[F4], während der Cursor auf der Formal steht, die Sie umwandeln wollen.

Wollen Sie jedoch absolute Bezüge wieder in relative Bezüge zurückverwandeln, müssen Sie entweder jedes $-Zeichen löschen oder jeweils dreimal [F4] drücken. Das lässt sich allerdings abkürzen:

  1. Markieren Sie zunächst den Bereich, in dem Sie die Bezüge umwandeln wollen.
  2. Wählen Sie aus dem Menü Bearbeiten den Eintrag Suchen und Ersetzen.
  3. Geben Sie unter Suchen nach das Zeichen $ ein und stellen Sie zugleich sicher, dass das Feld Ersetzen durch leer bleibt.
  4. Abschließend starten Sie den auswahlweiten Ersetzungsvorgang, indem Sie auf Alle ersetzen klicken. Calc wandelt dann alle absoluten Bezüge in relative Bezüge um.

Tipp: Calc: Zahlenformat plus Einheit

Angenommen, Sie haben eine Liste von Zahlen und wollen diese Zahlen um eine Einheit ergänzen – beispielsweise möchten Sie aus einer 3,5 eine 3,5 m machen. Das klappt, indem Sie ein benutzerdefiniertes Zahlenformat auf die Zellen anwenden. Markieren Sie dazu die Zellen mit den zu ergänzenden Zahlen und wählen Sie aus dem Kontextmenü den Eintrag Zellen formatieren. Das öffnet ein Fenster, in dem Sie als Kategorie den Eintrag Benutzerdefiniert wählen (Abbildung 1) und als Format-Code den String #,# \m eintippen – achten Sie auf das Leerzeichen vor \! Nach einem Klick auf OK ändert Calc die Zahlenformate.

Abbildung 1: Über einen Format-Code hängen Sie einzelne Zeichen an Zahlen an.

Tipp: Calc: Durchschnittsnote errechnen

Gehen Sie noch zur Schule, finden Sie mit Calc recht einfach heraus, welche Durchschnittsnote Sie in einem Schulfach erhalten. Wir gehen im Beispiel davon aus, dass Sie pro Schuljahr vier Schularbeiten und vier Stegreifaufgaben (Exen) schreiben, wobei die Note für eine Schularbeit die doppelte Wertigkeit besitzt. Natürlich kann das in Ihrem Bundesland etwas anders sein, in diesem Fall passen Sie die Formel an die Umstände an. Um das Problem zu lösen, erstellen Sie sich eine Tabelle wie in Abbildung 2.

Abbildung 2: Mit Hilfe einer Tabelle errechnen Sie die Durchschnittsnote aus den einzelnen Noten, die Sie über das Schuljahr erhalten.

Die Zeilen 1 bis 3 reservieren Sie für die Überschriften, in die Spalte A tragen Sie die Schulfächer ein. In den Spalten B bis E erfassen Sie die Schularbeiten, unter F bis I folgen die Extemporalen bzw. Stegreifaufgaben. In der Spalte J errechnet Calc schließlich die Jahresdurchschnittsnoten für die einzelnen Fächer. Dazu schreiben Sie – unter Zugrundelegung des oben abgebildeten Musters – folgende Formel:

=(SUMME(B4:E4)*2+SUMME(F4:I4))/(ANZAHL2(B4:E4)*2+ANZAHL2(F4:I4))

Kopieren Sie die Formel, die sich zunächst nur auf die Zeile 3 bezieht, in alle Zellen, in denen Sie eine Jahresdurchschnittsnote errechnen wollen.

Die Formel summiert im ersten Teil zunächst die Noten der geschriebenen Schularbeiten und multipliziert diese mit zwei (SUMME(B4:E4)*2) – wegen der doppelten Wertigkeit. Im nächsten Schritt addiert sie die Noten der Extemporalen dazu (+SUMME(F4:I4)). Die so errechnete Notensumme teilen Sie nun noch durch die Anzahl der geschriebenen Leistungstests, wobei die Schularbeiten wieder doppelt zählen. Damit die ausgewiesene Durchschnittsnote immer dem tatsächlichen Notendurchschnitt entspricht (und weil mitunter ungewiss ist, wie viele Schularbeiten Sie tatsächlich schreiben), summiert die Funktion ANZAHL2() die Zellen mit Noteneinträgen getrennt nach Schularbeiten und Extemporalen auf. Die errechnete Notensumme dividiert durch den errechneten Teiler ergibt die gesuchte Durchschnittsnote.

Tipp: Calc: Einnahmen pro Kalenderwoche

Sie haben sich in Calc eine kleine Einnahmeüberschussrechnung erstellt. In der Spalte A steht in A2 das Kalenderjahr, darunter folgen unsortiert die Daten der Eingaben. Wir nehmen an, Sie haben die Datumsangaben der Spalte A mit dem benutzerdefinierten Zahlenformat TT.MM.JJ -- WW KW versehen (Abbildung 3). Die Einnahmen stehen in der Spalte B, die Ausgaben erfasst die Spalte C.

Ab Spalte F folgen in der zweiten Zeile die Kalenderwochen. Die dritte Zeile listet die dazugehörenden Einnahmen der jeweiligen Kalenderwoche auf, die vierte die Ausgaben. In der fünften und letzten Zeile folgt schließlich der Wochenüberschuss.

Abbildung 3: Einnahmen und Ausgaben einer Woche ermitteln Sie mit Hilfe einer etwas längeren Formel getrennt.

In A2 schreiben Sie das Kalenderjahr als vierstellige Zahl, in F2 tragen Sie die Nummer der gewünschten Kalenderwoche per Hand ein. Im Feld darunter – F3 – folgen die Einnahmen, die Sie mit Hilfe einer Matrixformel ermitteln. Die nun folgende Berechnung sieht erst einmal kompliziert aus, wir dröseln sie jedoch weiter unten auf. Die Formel erfasst die Daten der Spalten A bis C:

=SUMME(WENN($A$3:$A$12<>"";(KALENDERWOCHE($A$3:$A$12;2)=F2)*(JAHR($A$3:$A$12)=$A$2)*$B$3:$B$12))

Beenden Sie die Eingabe dieser Matrixformel mit [Strg]+[Umschalt]+[Eingabe]. In die Zelle F4 (Ausgaben) tragen Sie dieselbe Formel ein wie in F3, ändern jedoch den Summenbereich zu $C$3:$C$12 (=letzter Teil der Formel), so dass sich folgende Formel ergibt:

=SUMME(WENN($A$3:$A$12<>"";(KALENDERWOCHE($A$3:$A$12;2)=F2)*(JAHR($A$3:$A$12)=$A$2)*$C$3:$C$12))

Auch diese Matrixformel schließen Sie über [Strg]+[Umschalt]+[Eingabe] ab.

Die Erklärung: Calc errechnet anhand der in Spalte A eingegebenen Datumswerte mit der Funktion KALENDERWOCHE(Bezug;Modus) die zutreffenden Kalenderwochennummern. Dabei legt der Parameter Modus den Wochenbeginn fest; tragen Sie hier 1 ein, beginnt die Woche am Sonntag, steht hier eine 2, startet sie am Montag.

Stimmt der so ermittelte Wert mit der in F2 bereits eingetragenen Kalenderwochennummer überein (=F2), ergibt sich der Wahrheitswert 1. Als nächstes prüft Calc, ob auch das Kalenderjahr der Zelle A2 mit dem Kalenderjahr des zu überprüfenden Datums übereinstimmt (JAHR($A$3:$A$12)=$A$2). Trifft auch das zu, ergibt sich wieder der Wahrheitswert 1, andernfalls kommt 0 heraus.

Nun weiß die Formel, in welchen Zellen die Werte zur Kalenderwoche in F2 stehen (im Beispiel KW 1) und das Rechnen beginnt. Durch die Multiplikation der beiden Wahrheitswerte mit dem entsprechenden Wert der Betragsspalten B ($B$3:$B$12) beziehungsweise – in der nächsten Formel – C ($C$3:$C$12) erhält Calc einen Wert, den es zur gesuchten Summe hinzufügt und in der Formelzelle ausweist. Die Differenz der so errechneten Einnahmen bzw. Ausgaben ergibt in der Zeile vier den Überschuss:

=F3-F4.

In den anderen Spalten errechnen Sie nach demselben Schema die Summen der übrigen Kalenderwochen.

Tipp: Calc: Sonderzeichen entfernen oder einfügen

Eine in Calc erstellte Datenbank soll aus Kompatibilitätsgründen keine Umlaute oder Sonderzeichen enthalten. Wie lassen sich diese Zeichen also ersetzen? Die Lösung ist nicht schwierig. In der Spalte A stehen in diesem Beispiel die Namen mit den Umlauten und Sonderzeichen, in der Spalte C sollen diese nach der Transformation auftauchen (Abbildung 4). Dazu schreiben Sie in C2 einfach die Formel:

=WECHSELN(WECHSELN(WECHSELN(WECHSELN(A2;"ß";"ss");"ä";"ae");"ö";"oe");"ü";"ue")

Sie ziehen die Formel dann über alle benötigten Zeilen der Spalte C und wenden sie so auf die Zellen an. Dazu markieren Sie die Zelle C2, klicken auf den kleinen, schwarzen, viereckigen Punkt darunter und ziehen diesen mit der gedrückten linken Maustaste über alle anderen Zellen, in denen Sie die Umlaute konvertieren wollen. Als Ergebnis erhalten Sie die Namen und Zeichenketten in den markierten Zellen umlaut- und sonderzeichenfrei.

Abbildung 4: Eine verschachtelte Formel mit der Funktion "WECHSELN()" ersetzt die Umlaute und Sonderzeichen in Texten durch einfache Vokale und Konsonanten.

Die Funktion WECHSELN(Text;Suchtext;Textersatz) lässt sich verschachteln. Dank ihr sucht Calc nach allen möglichen (in der Funktion unter den Suchtexten eingetragenen) Umlauten und tauscht diese gegen das entsprechende Selbstlautpaar aus.

Natürlich ist auch der umgekehrte Weg möglich. Benutzen Sie dazu die Formel:

=WECHSELN(WECHSELN(WECHSELN(WECHSELN(A2;"ss";"ß");"ae";"ä");"oe";"ö");"ue";"ü")

Allerdings lauern in dieser Formel auch Stolperfallen: Nicht immer sollte ein ue zu einem ü werden! Bei Worten wie bauen, Poet oder Metaebene wäre das fatal, eine genaue Korrektur lohnt sich also allemal!

Tipp: Calc: Namen verdrehen

Sie haben eine unsortierte Adressliste importiert, in der Vornamen und Nachnamen in derselben Zelle stehen. Nun möchten Sie in einer anderen Zelle die Namen umdrehen, so dass zuerst der Familienname erscheint, damit Sie die Liste nach Familiennamen sortieren können (Abbildung 5). Auch das gelingt mit einer Formel. Steht in A2 der Name Max Mustermann, schreiben Sie in C2 folgende Formel:

=TEIL(A2;FINDEN(" ";A2)+1;99)&" "&LINKS(A2;FINDEN(" ";A2)+0)

damit der Nachname an erster Stelle steht. Als Ergebnis erhalten Sie: Mustermann Max.

Abbildung 5: Namensdreher: Vor- und Nachname vertauschen Sie mit einer simplen Formel – diese versagt allerdings, sobald mehrere Vornamen in Spiel kommen.

Calc sucht hier zuerst über die Funktion FINDEN(" ";A2) nach dem Leerzeichen, das den Vor- vom Familiennamen trennt und schneidet dann ab dem ersten Zeichen danach (TEIL( A2[...]+1;99)) den restlichen Text aus – aber höchstens 99 Zeichen. Dem so gefundenen Familienname fügt die Formel dann ein Leerzeichen hinzu (&" "&) und ergänzt anschließend den Vornamen. Diesen bestimmt die Formel über die Funktion LINKS(): Sie schneidet den Vornamen aus, indem sie mit den Buchstaben ganz links beginnt und sich von dort bis zum nächsten Leerzeichen hangelt. Die Formel funktioniert übrigens nicht, wenn die Person in Spalte A mehr als einen Vornamen besitzt.

Mit Hilfe einer kleinen Anpassung löst die Formel auch andere Probleme. Importiert Calc Daten mit Datentrennern, tauchen nicht selten Kommata als Trenner auf. Möchten Sie solche Adressdaten (Abbildung 5, Zeile 3) umdrehen, müssen Sie die Formel in C3 wie folgt ändern:

=TEIL(A3;FINDEN(",";A3)+2;99)&" "&LINKS(A3;FINDEN(",";A3)-1)

Sie können auch nachträglich ein Komma hinzufügen (Abbildung 5, Zeile 4). Dazu passen Sie die Formel in C4 nur minimal an und setzen ein Komma zwischen die beiden Anführungszeichen:

=TEIL(A4;FINDEN(" ";A4)+1;99)&", "&LINKS(A4;FINDEN(" ";A4)+0)

Tipp: Calc: Zeichenfolgen wiederholen

Sie wollen die Zahl in der Zelle A1 in einer anderen Zelle nochmals ausweisen. Dabei soll vor dieser Zahl sieben Mal das Zeichen * und nach der Zahl das ¤-Zeichen. Abbildung 6 zeigt, wie das konkret aussieht: In A1 steht die Zahl 3.500,25 (die Formatierung weicht hier ein wenig vom Standard ab, was Sie über Zellen formatieren erreichen), in die Zelle B1 gehört dann die Formel:

=WIEDERHOLEN("*";7)&A1&" ¤"

Als Ergebnis erhalten Sie "*******3500,25 ¤".

Abbildung 6: Den freien Raum füllt Calc mit Sternchen auf und greift dabei zur Funktion WIEDERHOLEN().

Die Funktion WIEDERHOLEN(Text;Anzahl) schreibt zunächst sieben Mal das Zeichen *. Über & verknüpfen Sie anschließend den Inhalt der Zelle A1 mit den Sternchen und hängen – über ein weiteres & – das ¤-Zeichen an das Ende der Kette. Zugleich wandelt diese Formel die Zahl 3.500,25 in den Text 3500,25 um, so dass sämtliche Zahlenformate verloren gehen und der neue Text linksbündig erscheint. Schuld daran sind die vorangestellten Sternchen, die aus der Zahl automatisch eine Zeichenkette machen.

Eine Alternative stellt folgende Formel dar:

=WIEDERHOLEN("*";20)&TEXT(A1;"#.###,00 ¤")

Diese Formel schreibt zwanzig Mal ein Sternchen und hängt dann den Inhalt der Zelle A1 direkt als formatierten Text hinten dran (Abbildung 7). Der Unterschied besteht darin, dass der Eurobetrag hier das Tausendertrennzeichen nicht entfernt. Richten Sie den Inhalt der Zelle zusätzlich rechts aus, füllt das den gesamten nicht von Zahlen belegten Teil der Zelle mit Sternchen aus – eine optimale Methode, um Zellen vor Zahlenfälschungen zu schützen.

Abbildung 7: Setzen Sie Sternchen ein, entwertet das automatisch die Betragszellen.

Tipp: Writer: Trennlinien schnell entfernen

Bekanntlich fügen Sie in ein Writer-Dokument einen Trennstrich ein, indem Sie drei aufeinander folgende Bindestriche eingeben und [Eingabe] drücken. Je nach verwendetem Zeichen (*, =, -, _) erhalten Sie anders formatierte Linien.

Wollen Sie eine so eingefügte Linie im Nachhinein wieder entfernen, klicken Sie üblicherweise in die Zeile über der Linie, rufen den Befehl Format / Absatz auf, wechseln zur Registerkarte Umrandung und klicken bei Linienanordnung im Abschnitt Standard auf die erste Schaltfläche.

Es geht aber auch viel schneller: Dazu klicken Sie mit der rechten Maustaste auf die Zeile über der Linie und wählen aus dem Kontextmenü, das Sie über die rechte Maustaste erreichen, den Befehl Standardformatierung. Voilà – der Strich ist verschwunden.

Tipp: Writer: Zahlen in Tabellen automatisch formatieren

Fügen Sie in LibreOffice Writer eine Tabelle ein und tippen Sie 5,80 ¤ in eine Zelle, so erscheint diese Zahl linksbündig wie eingegeben. Möchten Sie, dass Writer eingegebene Zahlen und Währungsbeträge grundsätzlich automatisch erkennt, zweistellig formatiert und rechtsbündig ausrichtet, müssen Sie diese Funktion zuerst in den Optionen aktivieren.

Dazu wählen Sie Extras / Optionen und dann die Kategorien LibreOffice Writer / Tabelle sowie LibreOffice Writer/Web / Tabelle – beide Kategorien enthalten den Eintrag Tabelle. Im rechten oberen Abschnitt des Fensters stoßen Sie auf die Option Eingabe in Tabellen.

Aktivieren Sie die Kontrollkästchen Zahlenerkennung, Zahlenformaterkennung und Ausrichtung, um das gewünschte Writer-Verhalten festzulegen (Abbildung 8). Wenn Sie nach dem Aktivieren dieser Optionsfelder 5,80 ¤ eingeben und die Zelle durch Drücken von [Tab] verlassen, zeigt Writer das gewünschte Ergebnis in der Zelle an (Abbildung 9).

Abbildung 8: Über die Optionen von LibreOffice aktivieren Sie die automatische Zahlenerkennung.
Abbildung 9: Dank der automatischen Zahlenerkennung formatiert Writer Werte, die Sie in Tabellen eintragen.

Möchten Sie die automatische Zahlenerkennung nicht grundsätzlich einschalten, können Sie der Tabellenzelle auch jeweils im Vorfeld mitteilen, dass die nachfolgende Eingabe als Zahl zu interpretieren ist. Markieren Sie die entsprechende Zelle oder Zellen, und setzen Sie dann im Kontextmenü ein Häkchen vor Zahlenerkennung. Zusätzlich weisen Sie der Zelle bei Bedarf über das Kontextmenü ein Zahlenformat zu.

Tipp: Writer: Mehrseitige Texte mit der Maus markieren

Wollen Sie einen langen Text markieren, ist dies nicht so einfach – vor allem, wenn die Markierung mehrere Seiten umfasst. Es gibt jedoch eine Methode die immer funktioniert: Setzen Sie den Cursor an den Anfang der zu markierenden Textpassage. Nun scrollen Sie mit der Maus so lange den Text hinunter, bis Sie an die gewünschte Zielposition gelangen. Halten Sie nun [Umschalt] gedrückt und klicken Sie mit der Maus an die Stelle im Text, an der die Markierung enden soll. Das wählt den kompletten Text zwischen der ersten Markierung und dem zweiten Mausklick aus.

Diesen Artikel als PDF kaufen

Express-Kauf als PDF

Umfang: 4 Heftseiten

Preis € 0,99
(inkl. 19% MwSt.)

LinuxCommunity kaufen

Einzelne Ausgabe
 
Abonnements
 

Related content

Kommentare